Forum ORANGE Migration

#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=LBMonitor.ico
#AutoIt3Wrapper_UseUpx=y
#AutoIt3Wrapper_Res_Fileversion=1.0
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#include <ButtonConstants.au3>
#include <ComboConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include<File.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("LBMonitor", 266, 99, 316, 176)
$Combo1 = GUICtrlCreateCombo("", 16, 16, 145, 25)
GUICtrlSetData($Combo1, "ErroredSecs|SeverelyErroredSecs|FECErrors|ATUCFECErrors|HECErrors|ATUCHECErrors|CRCErrors|ATUCCRCErrors|UpstreamNoiseMargin|DownstreamNoiseMargin|UpstreamAttenuation|DownstreamAttenuation", "ErroredSecs")
$Button1 = GUICtrlCreateButton("Graph", 176, 16, 75, 25)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###
Opt("TrayIconHide", 1) ;0=show, 1=hide tray icon

Global $USER = "admin"
Global $LIVEBOX = "livebox"
Global $sContextID = ""
Global $PASSWORD = ""



; On vérifie que le fichier INI est bien présent
$sFilePath = @scriptDir & "\config.ini"
$iFileExists = FileExists($sFilePath)
if $iFileExists Then
    Global $LIVEBOX = IniRead (@scriptDir & "\config.ini","setting","LiveboxIP","192.168.1.1")
    Global $PASSWORD = IniRead (@scriptDir & "\config.ini","setting","password","")
Else
    $Filepath = @ScriptDir & "\config.ini"
    FileOpen($Filepath, 1)
    FileWriteLine($Filepath,"[setting]")
    FileWriteLine($Filepath,"LiveboxIP=192.168.1.1")
    FileWriteLine($Filepath,"password=XXXXXXXX")
    msgbox(48,"ERREUR","Veuillez indiquer votre mot de passe Livebox dans le fichier CONFIG.INI")
    Exit
EndIf

; On vérifie que les étourdis ont bien mis leur mot de passe
if ($PASSWORD ="" or $PASSWORD="XXXXXXXX") Then
    msgbox(48,"ERREUR","Veuillez indiquer votre mot de passe Livebox dans le fichier CONFIG.INI")
    Exit
EndIf



$oHTTP = ObjCreate("winhttp.winhttprequest.5.1")

auth_livebox()

_GetData()

AdlibRegister("_GetData",60000) ; execute la fonction _GetData toutes les 60 secondes

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            _Logout()
            Exit

        Case $Button1
            _GetChart()

    EndSwitch
WEnd


Func _GetData()
; Recuperation des donnees DSLStats
$oHTTP.Open("POST", "http://" & $LIVEBOX & "/sysbus/NeMo/Intf/dsl0:getDSLStats", False)
$oHTTP.SetRequestHeader("X-Context", $sContextID)
$oHTTP.Send('{"parameters":{}}')
$getDSLStats = $oHTTP.ResponseText

; Recuperation des donnees MIBs
$oHTTP.Open("POST", "http://" & $LIVEBOX & "/sysbus/NeMo/Intf/data:getMIBs", False)
$oHTTP.SetRequestHeader("X-Context", $sContextID)
$oHTTP.Send('{"parameters":{"mibs":"dsl","flag":"","traverse":"down"}}')
$getMIBs = $oHTTP.ResponseText

$ErroredSecs = StringRegExp($getDSLStats, 'ErroredSecs":(.*),"SeverelyErroredSecs', 3)
$SeverelyErroredSecs = StringRegExp($getDSLStats, 'SeverelyErroredSecs":(.*),"FECErrors', 3)
$FECErrors = StringRegExp($getDSLStats, 'FECErrors":(.*),"ATUCFECErrors', 3)
$ATUCFECErrors = StringRegExp($getDSLStats, 'ATUCFECErrors":(.*),"HECErrors', 3)
$HECErrors = StringRegExp($getDSLStats, 'HECErrors":(.*),"ATUCHECErrors', 3)
$ATUCHECErrors = StringRegExp($getDSLStats, 'ATUCHECErrors":(.*),"CRCErrors', 3)
$CRCErrors = StringRegExp($getDSLStats, 'CRCErrors":(.*),"ATUCCRCErrors', 3)
$ATUCCRCErrors = StringRegExp($getDSLStats, 'ATUCCRCErrors":(.*)}}', 3)

$UpstreamNoiseMargin = StringRegExp($getMIBs, 'UpstreamNoiseMargin":(.*),"DownstreamNoiseMargin', 3)
$DownstreamNoiseMargin = StringRegExp($getMIBs, 'DownstreamNoiseMargin":(.*),"UpstreamAttenuation', 3)
$UpstreamAttenuation = StringRegExp($getMIBs, 'UpstreamAttenuation":(.*),"DownstreamAttenuation', 3)
$DownstreamAttenuation = StringRegExp($getMIBs, 'DownstreamAttenuation":(.*),"UpstreamPower', 3)


$data = @HOUR & ":" & @MIN & "," & _
$ErroredSecs[0] & "," & _
$SeverelyErroredSecs[0] & "," & _
$FECErrors[0] & "," & _
$ATUCFECErrors[0] & "," & _
$HECErrors[0] & "," & _
$ATUCHECErrors[0] & "," & _
$CRCErrors[0] & "," & _
$ATUCCRCErrors[0] & "," & _
$UpstreamNoiseMargin[0] & "," & _
$DownstreamNoiseMargin[0] & "," & _
$UpstreamAttenuation[0] & "," & _
$DownstreamAttenuation[0]

$filename = @YEAR & @MON & @MDAY & ".txt"
$Filepath = fileopen(@SCRIPTDIR & "\data\" & $filename,9)

FileWriteLine($Filepath,$data)
Fileclose($Filepath)

Endfunc ;==>_GetData

Func _GetChart()
    $link = "http://www.chartgo.com/preview.do?"
    $params = "&charttype=line&width=900&height=400&chrtbkgndcolor=white&labelorientation=vertical&fonttypetitle=bold&fonttypelabel=normal&gridlines=1&transparency=1&group1=Group+1&viewsource=mainView&language=fr"

    $choix = GUICtrlRead($Combo1)
    select
        Case $choix = "ErroredSecs"
            Local $c=2, $ytitle="&ytitle=Erreurs"
        Case $choix = "SeverelyErroredSecs"
            Local $c=3, $ytitle="&ytitle=Erreurs"
        Case $choix = "FECErrors"
            Local $c=4, $ytitle="&ytitle=Erreurs"
        Case $choix = "ATUCFECErrors"
            Local $c=5, $ytitle="&ytitle=Erreurs"
        Case $choix = "HECErrors"
            Local $c=6, $ytitle="&ytitle=Erreurs"
        Case $choix = "ATUCHECErrors"
            Local $c=7, $ytitle="&ytitle=Erreurs"
        Case $choix = "CRCErrors"
            Local $c=8, $ytitle="&ytitle=Erreurs"
        Case $choix = "ATUCCRCErrors"
            Local $c=9, $ytitle="&ytitle=Erreurs"
        Case $choix = "UpstreamNoiseMargin"
            Local $c=10, $ytitle="&ytitle=dB"
        Case $choix = "DownstreamNoiseMargin"
            Local $c=11, $ytitle="&ytitle=dB"
        Case $choix = "UpstreamAttenuation"
            Local $c=12, $ytitle="&ytitle=dB"
        Case $choix = "DownstreamAttenuation"
            Local $c=13, $ytitle="&ytitle=dB"
    EndSelect

    $title = "&title=" & $choix & " " & @YEAR & "/" & @MON & "/" & @MDAY

    $filename = @YEAR & @MON & @MDAY & ".txt"
    $lines = _FileCountLines(@SCRIPTDIR & "\data\" & $filename)
    $Filepath = fileopen(@SCRIPTDIR & "\data\" & $filename,0)

    Local $x="&xaxis1=", $y = "&yaxis1="

    For $i = 1 to $lines
        $line = FileReadLine($Filepath)
        $data = StringSplit($line,",")
        $x = $x & $data[1] & "%0D%0A"
        if $c>9 Then ; on affiche les dB correctement
            $data[$c] = $data[$c] / 10
        EndIf
        $y = $y & $data[$c] & "%0D%0A"
    Next
    Fileclose($Filepath)

    $hDownload = InetGet($link & $title & $ytitle & $x & $y & $params, @ScriptDir & "\graph\" & $choix & ".png", 1)
    InetClose($hDownload)
    shellexecute(@ScriptDir & "\graph\" & $choix & ".png")

EndFunc   ;==>_GetChart


Func _Logout()
    $oHTTP.Open("POST", "http://" & $LIVEBOX, False)
    $oHTTP.Send()
    $oHTTP = 0
EndFunc   ;==>_Logout


Func auth_livebox()
    $str = "/authenticate?username=" & $USER & "&password=" & $PASSWORD
    $oHTTP.Open("POST", "http://" & $LIVEBOX & $str, False)
    $oHTTP.SetRequestHeader("Content-Type", "application/json")
    $oHTTP.Send()
    $oReceived = $oHTTP.ResponseText
    $sContextID = StringRegExp($oReceived, 'contextID":"([^"]+)"|()$', 1)[0]
    If $sContextID = "" Then
        MsgBox(48, "ERREUR", " Mot de passe incorrect : ")
        Return "NOLOGIN"
    EndIf
EndFunc   ;==>auth_livebox